100 POKE53281,11:POKE53280,11:POKE646,15
110 PRINT"[147]"
120 PRINT" DU MUSST DIR JETZT MAL VORSTELLEN,"
130 PRINT"DASS DU GERADE IN EINEM PROGRAMM BIST,"
140 PRINT"DAS EINE EINGABE VON DIR ERWARTET."
150 PRINT"(SOVIEL PHANTASIE TRAU ICH DIR ZU...)"
160 PRINT"DA UNTEN WARTET DER CURSOR, ABER DU HAST"
170 PRINT"GRAD KEINE AHNUNG, WAS DU AN DER STELLE"
180 PRINT"MACHEN SOLLST. - ERGO: DU DRUECKST   ?[146]"
190 PRINT""
200 W1=PEEK(214):W2=PEEK(211)
210 POKE214,W1:POKE211,W2:SYS58640
220 POKE204,0:PRINT" (EINGABE): ";
225 GETA$:IFA$=""THEN225
230 POKE204,128:PRINTA$:IFA$="?"THEN GOSUB260:GOTO210
239 A=ASC(A$):IFA>132ANDA<137THEN241
240 GOSUB300:PRINT"[147]DIES IS DOCH NUR EIN TEST!":POKE198,0:WAIT198,1:POKE198,0:GOTO110
241 IFB=1THENB=0:GOSUB300:FORT=1TO1000:NEXT:REM DIESE ZEILE KANN BEI >280< ENTFALLEN
245 ONA-132GOSUB800,400,500,600
250 GOTO110
260 K=49152:L=40:M=1068:N=11
270 FORJ=0TO5:FORI=0TO10:POKEK+(J*N)+I,PEEK(M+(L*J)+I):NEXTI,J
280 GOSUB320 : RETURN : REM  HIER KANN'S AUCH MIT ZEILE 300 WEITERGEHEN...
300 FORJ=0TO5:FORI=0TO10:POKEM+(L*J)+I,PEEK(K+(J*N)+I):NEXTI,J
310 RETURN
320 PRINT"":PRINT"[176][195][195][195][195][195][195][195][195][195][174]"
330 PRINT"[194]F1 = ENDE[194]"
340 PRINT"[194]F3 = MENU[194]"
350 PRINT"[194]F5 = INFO[194]"
360 PRINT"[194]F7 = SAVE[194]"
370 PRINT"[173][195][195][195][195][195][195][195][195][195][189]"
380 B=1:RETURN
400 PRINT"[147]  HIER WAERE MAN BEIM 'MENUE'..."
410 GOSUB700:RETURN
500 PRINT"[147]  HIER WAERE MAN BEIM 'PROGRAMM-INFO'..."
510 GOSUB700:RETURN
600 PRINT"[147]  HIER WAERE MAN BEIM 'DISK-MENUE'..."
610 GOSUB700:RETURN
700 POKE198,0:WAIT198,1:POKE198,0:RETURN
800 PRINT"[147]   UND HIER IS SCHLUSS !":END